@@ -36,7 +36,7 @@ string-bench := bcopy bzero memccpy memchr memcmp memcpy memmem memmove \
strncasecmp strncat strncmp strncpy strnlen strpbrk strrchr \
strspn strstr strcpy_chk stpcpy_chk memrchr strsep strtok \
strcoll
-wcsmbs-bench := wcslen wcsnlen
+wcsmbs-bench := wcslen wcsnlen wcscpy
string-bench-all := $(string-bench) ${wcsmbs-bench}
# We have to generate locales
new file mode 100644
@@ -0,0 +1,20 @@
+/* Measure wcscpy functions.
+ Copyright (C) 2015 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#define WIDE 1
+#include "bench-strcpy.c"
@@ -1,9 +1,11 @@
ifeq ($(subdir),string)
sysdep_routines += strlen strlen-vx strlen-c \
- strnlen strnlen-vx strnlen-c
+ strnlen strnlen-vx strnlen-c \
+ strcpy strcpy-vx
endif
ifeq ($(subdir),wcsmbs)
sysdep_routines += wcslen wcslen-vx wcslen-c \
- wcsnlen wcsnlen-vx wcsnlen-c
+ wcsnlen wcsnlen-vx wcsnlen-c \
+ wcscpy wcscpy-vx wcscpy-c
endif
@@ -85,6 +85,9 @@ __libc_ifunc_impl_list (const char *name, struct libc_ifunc_impl *array,
IFUNC_VX_IMPL (strnlen);
IFUNC_VX_IMPL (wcsnlen);
+ IFUNC_VX_IMPL (strcpy);
+ IFUNC_VX_IMPL (wcscpy);
+
#endif /* HAVE_S390_VX_ASM_SUPPORT */
return i;
new file mode 100644
@@ -0,0 +1,107 @@
+/* Vector optimized 32/64 bit S/390 version of strcpy.
+ Copyright (C) 2015 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
+
+# include "sysdep.h"
+# include "asm-syntax.h"
+
+ .text
+
+/* char * strcpy (const char *dest, const char *src)
+ Copy string src to dest.
+
+ Register usage:
+ -r1=tmp
+ -r2=dest and return_value
+ -r3=src
+ -r4=tmp
+ -r5=current_len
+ -v16=part of src
+ -v17=index of zero
+ -v18=part of src
+*/
+ENTRY(__strcpy_vx)
+ .machine "z13"
+ .machinemode "zarch_nohighgprs"
+
+ lghi %r5,0 /* current_len = 0. */
+
+ /* Align s to 16 byte. */
+ risbg %r1,%r3,60,128+63,0 /* Test if s is aligned and
+ %r1 = bits 60-63 'and' 15. */
+ je .Lloop1 /* If s is aligned, loop aligned. */
+ lghi %r4,15
+ slr %r4,%r1 /* Compute highest index to load (15-x). */
+ vll %v16,%r4,0(%r3) /* Load up to 16 byte boundary. (vll needs
+ highest index, remaining bytes are 0.) */
+ vfenezb %v17,%v16,%v16 /* Find element not equal with zero search. */
+ vlgvb %r5,%v17,7 /* Load zero index or 16 if not found. */
+ clrjle %r5,%r4,.Lfound_align /* If found zero within loaded bytes,
+ copy bytes before and return. */
+ vstl %v16,%r4,0(%r2) /* Copy loaded characters - no zero. */
+ ahi %r4,1 /* Start loop at next character. */
+ lgr %r5,%r4 /* No zero within loaded bytes,
+ process further bytes aligned. */
+ j .Lloop1
+
+.Lfound_align:
+ vstl %v16,%r5,0(%r2) /* Copy characters including zero. */
+ br %r14
+
+ /* Find zero in 16byte aligned loop. */
+.Lloop2:
+ vst %v18,0(%r5,%r2) /* Store previous part without zero to dst. */
+ aghi %r5,16
+.Lloop1:
+ vl %v16,0(%r5,%r3) /* Load s. */
+ vfenezbs %v17,%v16,%v16 /* Find element not equal with zero search. */
+ je .Lfound_v16 /* Jump away if zero was found. */
+ vl %v18,16(%r5,%r3)/* Load next part of s. */
+ vst %v16,0(%r5,%r2) /* Store previous part without zero to dst. */
+ aghi %r5,16
+ vfenezbs %v17,%v18,%v18
+ je .Lfound_v18
+ vl %v16,16(%r5,%r3)
+ vst %v18,0(%r5,%r2)
+ aghi %r5,16
+ vfenezbs %v17,%v16,%v16
+ je .Lfound_v16
+ vl %v18,16(%r5,%r3)
+ vst %v16,0(%r5,%r2)
+ aghi %r5,16
+ vfenezbs %v17,%v18,%v18
+ jo .Lloop2 /* No zero found -> loop. */
+
+.Lfound_v18:
+ vlr %v16,%v18
+.Lfound_v16:
+ la %r3,0(%r5,%r2)
+ vlgvb %r1,%v17,7 /* Load byte index of zero. */
+ vstl %v16,%r1,0(%r3) /* Store characters including zero. */
+ br %r14
+END(__strcpy_vx)
+
+/* Use mvst-strcpy-implementation as default implementation. */
+# define strcpy __strcpy_c
+# undef libc_hidden_builtin_def
+# define libc_hidden_builtin_def(name) strong_alias(__strcpy_c, __GI_strcpy)
+#endif /* HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc) */
+
+/* Include mvst-strcpy-implementation in s390-32/s390-64 subdirectory. */
+#include <strcpy.S>
new file mode 100644
@@ -0,0 +1,24 @@
+/* Multiple versions of strcpy.
+ Copyright (C) 2015 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
+# include <string.h>
+# include <ifunc-resolve.h>
+
+s390_vx_libc_ifunc2 (__strcpy, strcpy)
+#endif
new file mode 100644
@@ -0,0 +1,25 @@
+/* Default wcscpy implementation for S/390.
+ Copyright (C) 2015 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
+# define WCSCPY __wcscpy_c
+
+# include <wchar.h>
+extern __typeof (wcscpy) __wcscpy_c;
+# include <wcsmbs/wcscpy.c>
+#endif
new file mode 100644
@@ -0,0 +1,134 @@
+/* Vector optimized 32/64 bit S/390 version of wcscpy.
+ Copyright (C) 2015 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
+
+# include "sysdep.h"
+# include "asm-syntax.h"
+
+ .text
+
+/* char * wcscpy (const wchar_t *dest, const wchar_t *src)
+ Copy string src to dest.
+
+ Register usage:
+ -r0=border-len for switching to vector-instructions
+ -r1=tmp
+ -r2=dest and return value
+ -r3=src
+ -r4=tmp
+ -r5=current_len
+ -v16=part of src
+ -v17=index of zero
+ -v18=part of src
+*/
+ENTRY(__wcscpy_vx)
+ .machine "z13"
+ .machinemode "zarch_nohighgprs"
+
+ lghi %r5,0 /* current_len = 0. */
+ lghi %r0,16 /* Jump to vector-algorithmus after
+ at least 16 processed bytes. */
+
+ /* Align s to 16 byte */
+ risbg %r1,%r3,60,128+63,0 /* Test if s is aligned and
+ %r1 = bits 60-63 'and' 15. */
+ je .Lpreloop /* If s is aligned, loop aligned. */
+ tmll %r3,3 /* Test if s is 4-byte aligned? */
+ jne .Lfallback /* And use common-code variant if not. */
+ lghi %r4,16
+ slr %r4,%r1 /* Compute byte count (16-x). */
+ agr %r0,%r4 /* And add it to border-byte-len. */
+
+.Lpreloop:
+ /* Copy first 4 characters without vector algorithmus. */
+ lt %r1,0(%r5,%r3)
+ je .Lstore_r1_0_end
+ st %r1,0(%r5,%r2)
+ lt %r4,4(%r5,%r3)
+ je .Lstore_r1_4_end
+ st %r4,4(%r5,%r2)
+ lt %r1,8(%r5,%r3)
+ je .Lstore_r1_8_end
+ st %r1,8(%r5,%r2)
+ lt %r4,12(%r5,%r3)
+ je .Lstore_r1_12_end
+ st %r4,12(%r5,%r2)
+ aghi %r5,16 /* Processed first 4 characters. */
+ clije %r0,16,.Lloop1 /* Continue with vector algorithm. */
+.Lpreloop_loop:
+ lt %r1,0(%r5,%r3)
+ je .Lstore_r1_0_end
+ st %r1,0(%r5,%r2)
+ aghi %r5,4
+ clrjh %r0,%r5,.Lpreloop_loop
+ j .Lloop1 /* Proceed with vector algorithmus. */
+
+.Lstore_r1_0_end:
+ st %r1,0(%r5,%r2)
+ br %r14
+.Lstore_r1_4_end:
+ st %r4,4(%r5,%r2)
+ br %r14
+.Lstore_r1_8_end:
+ st %r1,8(%r5,%r2)
+ br %r14
+.Lstore_r1_12_end:
+ st %r4,12(%r5,%r2)
+ br %r14
+
+ /* Find zero in 16byte aligned loop. */
+.Lloop2:
+ vst %v18,0(%r5,%r2) /* Store previous part without zero to dst. */
+ aghi %r5,16
+.Lloop1:
+ vl %v16,0(%r5,%r3) /* Load s. */
+ vfenezfs %v17,%v16,%v16 /* Find element not equal with zero search. */
+ je .Lfound_v16 /* Jump away if zero was found. */
+ vl %v18,16(%r5,%r3) /* Load next part of s. */
+ vst %v16,0(%r5,%r2) /* Store previous part without zero to dst. */
+ aghi %r5,16
+ vfenezfs %v17,%v18,%v18
+ je .Lfound_v18
+ vl %v16,16(%r5,%r3)
+ vst %v18,0(%r5,%r2)
+ aghi %r5,16
+ vfenezfs %v17,%v16,%v16
+ je .Lfound_v16
+ vl %v18,16(%r5,%r3)
+ vst %v16,0(%r5,%r2)
+ aghi %r5,16
+ vfenezfs %v17,%v18,%v18
+ jo .Lloop2 /* No zero found -> loop. */
+
+.Lfound_v18:
+ vlr %v16,%v18
+.Lfound_v16:
+ la %r3,0(%r5,%r2)
+ vlgvb %r1,%v17,7 /* Load byte index of zero. */
+ aghi %r1,3 /* Also copy remaining bytes of zero. */
+ vstl %v16,%r1,0(%r3) /* Copy characters including zero. */
+ br %r14
+.Lfallback:
+ /* Common-code cannot handle non 4-byte aligned wchar_t-pointers, too.
+ Write a terminating null to dest and return! */
+ lhi %r1,0
+ st %r1,0(%r2)
+ br %r14
+END(__wcscpy_vx)
+#endif /* HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc) */
new file mode 100644
@@ -0,0 +1,27 @@
+/* Multiple versions of wcscpy.
+ Copyright (C) 2015 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+#if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
+# include <wchar.h>
+# include <ifunc-resolve.h>
+
+s390_vx_libc_ifunc2 (__wcscpy, wcscpy)
+
+#else
+# include <wcsmbs/wcscpy.c>
+#endif /* !(defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)) */
new file mode 100644
@@ -0,0 +1,21 @@
+/* Multiple versions of strcpy.
+ Copyright (C) 2015 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+/* This wrapper-file is needed, because otherwise file
+ sysdeps/s390/s390-[32|64]/strcpy.S will be used. */
+#include <sysdeps/s390/multiarch/strcpy.c>
new file mode 100644
@@ -0,0 +1,21 @@
+/* Multiple versions of strcpy.
+ Copyright (C) 2015 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <http://www.gnu.org/licenses/>. */
+
+/* This wrapper-file is needed, because otherwise file
+ sysdeps/s390/s390-[32|64]/strcpy.S will be used. */
+#include <sysdeps/s390/multiarch/strcpy.c>