diff mbox series

[03/17] riscv: add vectorized strchr

Message ID	20260716150048.216052-4-pincheng.plct@isrc.iscas.ac.cn
State	New
Headers	DMARC-Filter: OpenDMARC Filter v1.4.2 sourceware.org DF8524BA23F0 From: Pincheng Wang <pincheng.plct@isrc.iscas.ac.cn> To: newlib@sourceware.org Cc: Pincheng Wang <pincheng.plct@isrc.iscas.ac.cn> Subject: [PATCH 03/17] riscv: add vectorized strchr Date: Thu, 16 Jul 2026 23:00:34 +0800 Message-Id: <20260716150048.216052-4-pincheng.plct@isrc.iscas.ac.cn> In-Reply-To: <20260716150048.216052-1-pincheng.plct@isrc.iscas.ac.cn> References: <20260716150048.216052-1-pincheng.plct@isrc.iscas.ac.cn> MIME-Version: 1.0 Content-Transfer-Encoding: 8bit Precedence: list Errors-To: newlib-bounces~patchwork=sourceware.org@sourceware.org
Series	riscv: vectorized str* routines \| [00/17] riscv: vectorized str* routines [01/17] riscv: add vectorized strlen [02/17] riscv: add vectorized strnlen [03/17] riscv: add vectorized strchr [04/17] riscv: add vectorized strchrnul [05/17] riscv: add vectorized strrchr [06/17] riscv: add vectorized strcmp [07/17] riscv: add vectorized strncmp [08/17] riscv: add vectorized strcpy [09/17] riscv: add vectorized strncpy [10/17] riscv: add vectorized strcat [11/17] riscv: add vectorized strncat [12/17] riscv: add vectorized strspn [13/17] riscv: add vectorized strcspn [14/17] riscv: add vectorized strpbrk [15/17] riscv: add vectorized strstr [16/17] riscv: add vectorized strcasecmp [17/17] riscv: add vectorized strncasecmp

Commit Message

Pincheng Wang July 16, 2026, 3 p.m. UTC

  The vector implementation scans the string in vector-length chunks using
fault-only-first loads (vle8ff.v), locating the target byte and the
terminating NUL in the same pass while never crossing into an unmapped
page.  This provides significant performance improvements on RVV-capable
hardware.  Use conditional compilation to fall back to the generic
implementation when __riscv_vector is not available, maintaining
compatibility with non-vector RISC-V systems.

Signed-off-by: Pincheng Wang <pincheng.plct@isrc.iscas.ac.cn>
---
 newlib/libc/machine/riscv/Makefile.inc |  2 ++
 newlib/libc/machine/riscv/strchr-asm.S | 29 ++++++++++++++++++++++++++
 newlib/libc/machine/riscv/strchr.c     |  5 +++++
 3 files changed, 36 insertions(+)
 create mode 100644 newlib/libc/machine/riscv/strchr-asm.S
 create mode 100644 newlib/libc/machine/riscv/strchr.c

diff mbox series

Patch

diff --git a/newlib/libc/machine/riscv/Makefile.inc b/newlib/libc/machine/riscv/Makefile.inc
index d3f72e471..01a0aaf50 100644
--- a/newlib/libc/machine/riscv/Makefile.inc
+++ b/newlib/libc/machine/riscv/Makefile.inc
@@ -20,6 +20,8 @@  libc_a_SOURCES += \
 	%D%/memset.S \
 	%D%/setjmp.S \
 	%D%/stpcpy.c \
+	%D%/strchr-asm.S \
+	%D%/strchr.c \
 	%D%/strcmp.S \
 	%D%/strcpy.c \
 	%D%/strlen-asm.S \
diff --git a/newlib/libc/machine/riscv/strchr-asm.S b/newlib/libc/machine/riscv/strchr-asm.S
new file mode 100644
index 000000000..79faf8273
--- /dev/null
+++ b/newlib/libc/machine/riscv/strchr-asm.S
@@ -0,0 +1,29 @@ 
+#if defined(__riscv_vector) && __riscv_xlen == 64 && !defined(__OPTIMIZE_SIZE__) && !defined(PREFER_SIZE_OVER_SPEED)
+.text
+.option push
+.option arch, +v
+.global strchr
+.type strchr, @function
+strchr:
+.Lloop:
+  vsetvli t0, zero, e8, m1, ta, ma
+  vle8ff.v v0, (a0)
+  vmseq.vi v8, v0, 0
+  vmseq.vx v9, v0, a1
+  vfirst.m a2, v8      /* first occurrence of \0 */
+  vfirst.m a3, v9      /* first occurrence of a1 */
+  sltz a4, a3
+  sltu a5, a2, a3
+  or a4, a4, a5
+  beqz a4, .Lfound     /* found a1, not preceded by \0? */
+  csrr a6, vl
+  add a0, a0, a6
+  bltz a2, .Lloop      /* didn't find \0? */
+  li a0, 0
+  ret
+.Lfound:
+  add a0, a0, a3
+  ret
+.size strchr, .-strchr
+.option pop
+#endif
diff --git a/newlib/libc/machine/riscv/strchr.c b/newlib/libc/machine/riscv/strchr.c
new file mode 100644
index 000000000..7a2f39aac
--- /dev/null
+++ b/newlib/libc/machine/riscv/strchr.c
@@ -0,0 +1,5 @@ 
+#if defined(__OPTIMIZE_SIZE__) || defined(PREFER_SIZE_OVER_SPEED) || !defined(__riscv_vector) || __riscv_xlen != 64
+# include "../../string/strchr.c"
+#else
+/* strchr defined in strchr-asm.S */
+#endif