[v7,1/8] arm: Add the clone3 wrapper
Checks
Context |
Check |
Description |
redhat-pt-bot/TryBot-apply_patch |
success
|
Patch applied to master at the time it was sent
|
linaro-tcwg-bot/tcwg_glibc_check--master-aarch64 |
warning
|
Patch failed to apply
|
linaro-tcwg-bot/tcwg_glibc_build--master-arm |
warning
|
Patch failed to apply
|
linaro-tcwg-bot/tcwg_glibc_build--master-aarch64 |
warning
|
Patch failed to apply
|
Commit Message
It follows the internal signature:
extern int clone3 (struct clone_args *__cl_args, size_t __size,
int (*__func) (void *__arg), void *__arg);
Checked on arm-linux-gnueabihf.
---
sysdeps/unix/sysv/linux/arm/clone3.S | 80 ++++++++++++++++++++++++++++
sysdeps/unix/sysv/linux/arm/sysdep.h | 1 +
2 files changed, 81 insertions(+)
create mode 100644 sysdeps/unix/sysv/linux/arm/clone3.S
Comments
* Adhemerval Zanella via Libc-alpha:
> + /* Do the syscall, the kernel expects:
> + r7: system call number:
> + r0: cl_args
> + r1: size */
> + push { r7 }
> + cfi_adjust_cfa_offset (4)
> + cfi_rel_offset (r7, 0)
> + ldr r7, =SYS_ify(clone3)
> + swi 0x0
> + cfi_endproc
> +
> + cmp r0, #0
> + beq 1f
> + pop {r7}
> +1:
> + .fnstart
> + .cantunwind
> + mov r0, r3
> + mov ip, r2
> + BLX (ip)
I think the stack is misaligned at the BNLX call because only one 4-byte
register is pushed.
Thanks,
Florian
On 11/08/23 07:17, Florian Weimer wrote:
> * Adhemerval Zanella via Libc-alpha:
>
>> + /* Do the syscall, the kernel expects:
>> + r7: system call number:
>> + r0: cl_args
>> + r1: size */
>> + push { r7 }
>> + cfi_adjust_cfa_offset (4)
>> + cfi_rel_offset (r7, 0)
>> + ldr r7, =SYS_ify(clone3)
>> + swi 0x0
>> + cfi_endproc
>> +
>> + cmp r0, #0
>> + beq 1f
>> + pop {r7}
>
>> +1:
>> + .fnstart
>> + .cantunwind
>> + mov r0, r3
>> + mov ip, r2
>> + BLX (ip)
>
> I think the stack is misaligned at the BNLX call because only one 4-byte
> register is pushed.
It should not matter because the stack is defined by the cl_args::stack
argument. We might add a alignment check on clone-internal.c, but I
think since it uses solely on internal usage, it should be required.
* Adhemerval Zanella Netto:
> On 11/08/23 07:17, Florian Weimer wrote:
>> * Adhemerval Zanella via Libc-alpha:
>>
>>> + /* Do the syscall, the kernel expects:
>>> + r7: system call number:
>>> + r0: cl_args
>>> + r1: size */
>>> + push { r7 }
>>> + cfi_adjust_cfa_offset (4)
>>> + cfi_rel_offset (r7, 0)
>>> + ldr r7, =SYS_ify(clone3)
>>> + swi 0x0
>>> + cfi_endproc
>>> +
>>> + cmp r0, #0
>>> + beq 1f
>>> + pop {r7}
>>
>>> +1:
>>> + .fnstart
>>> + .cantunwind
>>> + mov r0, r3
>>> + mov ip, r2
>>> + BLX (ip)
>>
>> I think the stack is misaligned at the BNLX call because only one 4-byte
>> register is pushed.
>
> It should not matter because the stack is defined by the cl_args::stack
> argument. We might add a alignment check on clone-internal.c, but I
> think since it uses solely on internal usage, it should be required.
You are right, my mistake.
Thanks,
Florian
new file mode 100644
@@ -0,0 +1,80 @@
+/* The clone3 syscall wrapper. Linux/arm version.
+ Copyright (C) 2023 Free Software Foundation, Inc.
+
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <https://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+#define _ERRNO_H 1
+#include <bits/errno.h>
+
+/* The userland implementation is:
+ int clone3 (struct clone_args *cl_args, size_t size,
+ int (*func)(void *arg), void *arg);
+
+ the kernel entry is:
+ int clone3 (struct clone_args *cl_args, size_t size);
+
+ The parameters are passed in registers from userland:
+ r0: cl_args
+ r1: size
+ r2: func
+ r3: arg */
+
+ .text
+ENTRY(__clone3)
+ /* Sanity check args. */
+ cmp r0, #0
+ ite ne
+ cmpne r1, #0
+ moveq r0, #-EINVAL
+ beq PLTJMP(syscall_error)
+
+ /* Do the syscall, the kernel expects:
+ r7: system call number:
+ r0: cl_args
+ r1: size */
+ push { r7 }
+ cfi_adjust_cfa_offset (4)
+ cfi_rel_offset (r7, 0)
+ ldr r7, =SYS_ify(clone3)
+ swi 0x0
+ cfi_endproc
+
+ cmp r0, #0
+ beq 1f
+ pop {r7}
+ blt PLTJMP(C_SYMBOL_NAME(__syscall_error))
+ RETINSTR(, lr)
+
+ cfi_startproc
+PSEUDO_END (__clone3)
+
+1:
+ .fnstart
+ .cantunwind
+ mov r0, r3
+ mov ip, r2
+ BLX (ip)
+
+ /* And we are done, passing the return value through r0. */
+ ldr r7, =SYS_ify(exit)
+ swi 0x0
+
+ .fnend
+
+libc_hidden_def (__clone3)
+weak_alias (__clone3, clone3)
@@ -362,6 +362,7 @@ __local_syscall_error: \
#define HAVE_CLOCK_GETTIME_VSYSCALL "__vdso_clock_gettime"
#define HAVE_CLOCK_GETTIME64_VSYSCALL "__vdso_clock_gettime64"
#define HAVE_GETTIMEOFDAY_VSYSCALL "__vdso_gettimeofday"
+#define HAVE_CLONE3_WRAPPER 1
#define LOAD_ARGS_0()
#define ASM_ARGS_0